[avram] String type field can't save a empty string?

[zw963]

Following is a single file script to reproduce this behavior:

require "pg"
require "avram"

class AppDatabase < Avram::Database
end

AppDatabase.configure do |settings|
  settings.credentials = Avram::Credentials.new(database: "test_db", username: "postgres", hostname: "localhost")
end

Avram.configure do |settings|
  settings.database_to_migrate = AppDatabase
  settings.lazy_load_enabled = true
end

class CreateUserAudit::V20250315162146 < Avram::Migrator::Migration::V1
  def migrate
    create table_for(UserAudit) do
      primary_key id : Int64
      add_timestamps

      add user_id : Int64
      add changed_column_name : String
      add from : String
      add to : String
    end

    create_index table_for(UserAudit), [:user_id, :changed_column_name]
  end

  def rollback
    drop table_for(UserAudit)
  end
end

Avram::Migrator::Runner.drop_db(true)
Avram::Migrator::Runner.create_db(true)
Avram::Migrator::Runner.new.run_next_migration

abstract class BaseModel < Avram::Model
  def self.database : Avram::Database.class
    AppDatabase
  end
end

class UserAudit < BaseModel
  table do
    column user_id : Int64
    column changed_column_name : String
    column from : String
    column to : String
  end
end

UserAudit::SaveOperation.create!(user_id: 1_i64, changed_column_name: "column_name", from: "", to: "foo")

When run above code, I get error like this:

 ╰──➤ $ crystal run 1.cr
Migrated CreateUserAudit::V20250315162146
Unhandled exception: Could not perform UserAudit::SaveOperation.

  ▸ from: is required
 (Avram::InvalidOperationError)
  from lib/avram/src/avram/save_operation.cr:246:7 in 'save!'
  from 1.cr:47:3 in 'create!:user_id:changed_column_name:from:to'
  from 1.cr:55:1 in '__crystal_main'
  from /home/zw963/Crystal/share/crystal/src/crystal/main.cr:129:5 in 'main_user_code'
  from /home/zw963/Crystal/share/crystal/src/crystal/main.cr:115:7 in 'main'
  from /home/zw963/Crystal/share/crystal/src/crystal/system/unix/main.cr:9:3 in 'main'
  from /usr/lib/libc.so.6 in '??'
  from /usr/lib/libc.so.6 in '__libc_start_main'
  from /home/zw963/.cache/crystal/crystal-run-1.tmp in '_start'
  from ???

I have no idea why this happen, AFAIK, the TEXT type column in postgresql can save a blank string, right?

 ╰──➤ $ psql
WARNING:  database "zw963" has a collation version mismatch
DETAIL:  The database was created using collation version 2.40, but the operating system provides version 2.41.
HINT:  Rebuild all objects in this database that use the default collation and run ALTER DATABASE zw963 REFRESH COLLATION VERSION, or build PostgreSQL with the right library version.
psql (17.2)
Type "help" for help.

zw963=# CREATE TABLE test_table (
    id SERIAL PRIMARY KEY,
    text_column TEXT
);
CREATE TABLE
zw963=# INSERT INTO test_table (text_column) VALUES ('');
INSERT 0 1
zw963=# select * from test_table;
 id | text_column
----+-------------
  1 |
(1 row)

zw963=#

[jwoertink]

This is correct behavior. Avram (and Lucky) treat empty strings the same as nil. This is because an empty string on a non-nilable field will usually lead to bugs. For example, imagine displaying a user's name on a page, but the name is an empty string. It might say " , your report is now ready".

I have an issue to document this luckyframework/website#1288 but I've just never got around to doing it 😂

You can do this:

table do
    column user_id : Int64
    column changed_column_name : String
    column from : String, allow_blank: true
    column to : String
  end

[zw963]

Thanks, add allow_blank: true work, but when add the validate_required for the from column, I expect the validate error raised, but there is no error, do you think this is a bug？

require "pg"
require "avram"

class AppDatabase < Avram::Database
end

AppDatabase.configure do |settings|
  settings.credentials = Avram::Credentials.new(database: "test_db", username: "postgres", hostname: "localhost")
end

Avram.configure do |settings|
  settings.database_to_migrate = AppDatabase
  settings.lazy_load_enabled = true
end

class CreateUserAudit::V20250315162146 < Avram::Migrator::Migration::V1
  def migrate
    create table_for(UserAudit) do
      primary_key id : Int64
      add_timestamps

      add user_id : Int64
      add changed_column_name : String
      add from : String
      add to : String
    end

    create_index table_for(UserAudit), [:user_id, :changed_column_name]
  end

  def rollback
    drop table_for(UserAudit)
  end
end

Avram::Migrator::Runner.drop_db(true)
Avram::Migrator::Runner.create_db(true)
Avram::Migrator::Runner.new.run_next_migration

abstract class BaseModel < Avram::Model
  def self.database : Avram::Database.class
    AppDatabase
  end
end

class UserAudit < BaseModel
  table do
    column user_id : Int64
    column changed_column_name : String
    column from : String, allow_blank: true
    column to : String
  end
end

class SaveUserAudit < UserAudit::SaveOperation
  before_save do
    validate_required user_id, changed_column_name, from, to
  end
end

# Expected raise error because validate_required from
UserAudit::SaveOperation.create!(user_id: 1_i64, changed_column_name: "column_name", from: "", to: "foo")

[jwoertink]

No, this isn't a bug. If you're allowing an empty string, then "" is valid. The validate_required should still work if from is nil, but not if it's "".